#!/usr/bin/perl -w
use strict;
use utf8;

# /========================================================================\ #
# | Copyright (C) 2007 Ioan A. Sucan,                                      | #
# | This program converts numbers up to one million into Interlingua words | #
# | Released under the GNU General Public License                          | #
# |------------------------------------------------------------------------| #
# | Ioan A. Sucan                                                  #_#     | #
# | http://ioan.sucan.info                                        (o o)    | #
# \============================================================ooo==U==ooo=/ #

my %numbers = (0 => 'zero', 1 => 'un', 2 => 'duo', 3 => 'tres', 4 => 'quatro', 
	       5 => 'cinque', 6 => 'sex', 7 => 'septe', 8 => 'octo', 9 => 'nove');

my %tens = (1 => 'dece', 2 => 'vinti', 3 => 'trenta', 4 => 'quaranta', 5 => 'cinquanta',
	    6 => 'sexanta', 7 => 'septanta', 8 => 'octanta', 9 => 'novanta');

use constant TEN      => 10;
use constant HUNDRED  => 100;
use constant THOUSAND => 1000;
use constant MILLION  => 1000000;
use constant BILLION  => 1000000000;

sub convert {
    my ($nr) = @_;
    
    return $numbers{$nr} if $nr < TEN;

    if ($nr < HUNDRED) {
	my $rest = $nr % TEN;
	my $ten  = ($nr - $rest) / TEN;
	return $tens{$ten}.($rest > 0 ? '-'.$numbers{$rest} : '');
    }
    
    if ($nr < THOUSAND) {
	my $rest = $nr % HUNDRED;
	my $hundreds = ($nr - $rest) / HUNDRED;
	my $result = ($hundreds == 1 ? 'cento' : convert($hundreds).' centos');
	return $result.($rest > 0 ? ' '.convert($rest) : '');
    }
    
    if ($nr < MILLION) {
	my $rest = $nr % THOUSAND;
	my $thousands = ($nr - $rest) / THOUSAND;
	my $result = ($thousands == 1 ? 'mille' : convert($thousands).' milles');
	return $result.($rest > 0 ? ' '.convert($rest) : '');
    }

    if ($nr < BILLION) {
	my $rest = $nr % MILLION;
	my $million = ($nr - $rest) / MILLION;
	return convert($million).' million'.($million > 1 ? 'es' : '').($rest > 0 ? ' '.convert($rest) : '');
    }

    return 'un milliardo' if $nr == BILLION;
    
    'infinite';
}

my $nr = <STDIN>; chomp($nr);

binmode STDOUT, ":utf8";
print $nr < 0 ? 'minus '.convert(-$nr) : convert($nr), "\n";