#!/usr/bin/perl -w
use strict;
use utf8;

# /=====================================================================\ #
# | Copyright (C) 2007 Ioan A. Sucan,                                   | #
# | This program converts numbers up to one million into English words  | #
# | Released under the GNU General Public License                       | #
# |---------------------------------------------------------------------| #
# | Ioan A. Sucan                                               #_#     | #
# | http://ioan.sucan.info                                     (o o)    | #
# \=========================================================ooo==U==ooo=/ #

my %numbers = (0 => 'zero', 1 => 'one', 2 => 'two', 3 => 'three', 4 => 'four', 
	       5 => 'five', 6 => 'six', 7 => 'seven', 8 => 'eight', 9 => 'nine',
	       10 => 'ten', 11 => 'eleven', 12 => 'twelve', 13 => 'thirteen',
	       14 => 'fourteen', 15 => 'fifteen', 16 => 'sixteen',
	       17 => 'seventeen', 18 => 'eighteen', 19 => 'nineteen');

my %tens = (2 => 'twenty', 3 => 'thirty', 4 => 'forty', 5 => 'fifty',
	    6 => 'sixty', 7 => 'seventy', 8 => 'eighty', 9 => 'ninety');

use constant TEN      => 10;
use constant HUNDRED  => 100;
use constant THOUSAND => 1000;
use constant MILLION  => 1000000;
use constant BILLION  => 1000000000;

sub convert {
    my ($nr) = @_;
    
    return $numbers{$nr} if $nr < 20;

    if ($nr < HUNDRED) {
	my $rest = $nr % TEN;
	my $ten  = ($nr - $rest) / TEN;
	return $tens{$ten}.($rest > 0 ? ' '.$numbers{$rest} : '');
    }
    
    if ($nr < THOUSAND) {
	my $rest = $nr % HUNDRED;
	my $hundreds = ($nr - $rest) / HUNDRED;
	return convert($hundreds).' hundred'.($rest > 0 ? ' and '.convert($rest) : '');
    }
    
    if ($nr < MILLION) {
	my $rest = $nr % THOUSAND;
	my $thousands = ($nr - $rest) / THOUSAND;
	return convert($thousands).' thousand'.($rest > 0 ? ' '.convert($rest) : '');
    }

    if ($nr < BILLION) {
	my $rest = $nr % MILLION;
	my $million = ($nr - $rest) / MILLION;
	return convert($million).' million'.($rest > 0 ? ' '.convert($rest) : '');
    }

    return 'one billion' if $nr == BILLION;
    
    'infinite';
}

my $nr = <STDIN>; chomp($nr);

binmode STDOUT, ":utf8";
print $nr < 0 ? 'minus '.convert(-$nr) : convert($nr), "\n";